无组件上传及注释 -pc6资讯

您的位置：首页 → 精文荟萃 → 软件资讯 → 无组件上传及注释

无组件上传及注释 时间：2004/10/8 13:36:00来源：本站整理作者：蓝点我要评论(0): 　先看看这个,以上传一个文件名为1111.txt里面内容为1111111111111111的文本文件为例。
以下是表单提交到服务器的数据，文件存储就是找到文件域中的数据存放为文件即可。

-----------------------------7d36022d06d8
Content-Disposition: form-data; name="file1"; filename="E:\1111.txt"
Content-Type: text/plain

1111111111111111
-----------------------------7d36022d06d8
Content-Disposition: form-data; name="Submit"

提交
-----------------------------7d36022d06d8--

************************************************

dim upfile_Stream

Class upload_5xSoft

dim Form,File,Version

Private Sub Class_Initialize
dim iStart,iFileNameStart,iFileNameEnd,iEnd,vbEnter,iFormStart,iFormEnd,theFile
dim strDiv,mFormName,mFormvalue,mFileName,mFileSize,mFilePath,iDivLen,mStr
Version="LYL上传系统，5xSoft主编,纯生注释。"
if Request.TotalBytes<1 then Exit Sub ''TotalBytes，返回浏览器发送的字节数

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''创建两个集合，Form用于存放非文本域数据，File用于存放文本域数据。
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
set Form=CreateObject("Scripting.Dictionary")
set File=CreateObject("Scripting.Dictionary")

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''创建一个二进制的数据数，用于存放表单提交上来的所有数据
''BinaryRead是返回一个POST请求发送到服务器的二进制信息
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
set upfile_Stream=CreateObject("Adodb.Stream")
upfile_Stream.mode=3
upfile_Stream.type=1
upfile_Stream.open
upfile_Stream.write Request.BinaryRead(Request.TotalBytes)

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''下面就是戏肉了！！
''下面有两个自己定义函数，首先解释一下先。
''inString，返回形参第二个参数在数据流里的位置。两个形参：1.起始位置；2.字符串。
''subString,返回两个位置间的字符串。两个形参：1.起始位置；2.结束位置。
''
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
vbEnter=Chr(13)&Chr(10) ''Chr(13)是回车，Chr(10)是换行（这句也注，高手们又要骂街了！）
iDivLen=inString(1,vbEnter)+1 ''找到第一个表单间隔符的结束位置
strDiv=subString(1,iDivLen) ''找到表单里的间隔符，赋给strDiv
iFormStart=iDivLen ''表单中第一个元素的开始位置
iFormEnd=inString(iformStart,strDiv)-1 ''表单第一个元素的结束位置

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
while iFormStart < iFormEnd ''这句不用注释了吧！！？？
iStart=inString(iFormStart,"name=""") ''找到元素名的开始位置
iEnd=inString(iStart+6,"""") ''找到元素名结束的位置
mFormName=subString(iStart+6,iEnd-iStart-6) ''找到元素名
iFileNameStart=inString(iEnd+1,"filename=""") ''找文件域中文件名

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''如果找到有文件名，即是此元素是一个文件域，否则是其它的元素
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
if iFileNameStart>0 and iFileNameStartiFileNameEnd=inString(iFileNameStart+10,"""") ''找到文件名的结束位置
mFileName=subString(iFileNameStart+10,iFileNameEnd-iFileNameStart-10)''找到文件名
iStart=inString(iFileNameEnd+1,vbEnter&vbEnter) ''找到该文件的开始位置
iEnd=inString(iStart+4,vbEnter&strDiv) ''找到该文件的结束位置

''''''''''''''''''''
''得到文件的大小
'''''''''''''''''''''
if iEnd>iStart then
mFileSize=iEnd-iStart-4
else
mFileSize=0
end if

'''''''''''''''''''''''''''''''''
''FileInfo是自定义类，用于存放文件信息和将文件数据保存为文件
'''''''''''''''''''''''''''''''''
set theFile=new FileInfo
theFile.FileName=getFileName(mFileName)
theFile.FilePath=getFilePath(mFileName)
theFile.FileSize=mFileSize
theFile.FileStart=iStart+4
theFile.FormName=FormName
file.add mFormName,theFile

''''''''''''''''''''''''''''''''''''''''''
''下面是处理非文件域元素
''
''''''''''''''''''''''''''''''''''''''''''
else
iStart=inString(iEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)

if iEnd>iStart then
mFormvalue=subString(iStart+4,iEnd-iStart-4)
else
mFormvalue=""
end if
form.Add mFormName,mFormvalue
end if

iFormStart=iformEnd+iDivLen ''将iFormStart指向下一个元素的开始
iFormEnd=inString(iformStart,strDiv)-1 ''将iFormEnd指向下一个元素的结束
wend
End Sub

''''''''''''''''''''''''''''''''''''''
''以下是两个自定义函数和一些获取文件信息的过程，基于算法不算复杂，请自行分析。
''注：upfile_Stream.Position 设置数据流的位置；
'' upfile_Stream.Read(1) 从数据流中读取一个字节，（是ASCII码）
''''''''''''''''''''''''''''''''''''''
Private Function subString(theStart,theLen)
dim i,c,stemp
upfile_Stream.Position=theStart-1
stemp=""
for i=1 to theLen
if upfile_Stream.EOS then Exit for
c=ascB(upfile_Stream.Read(1))
If c > 127 Then
if upfile_Stream.EOS then Exit for
stemp=stemp&Chr(AscW(ChrB(AscB(upfile_Stream.Read(1)))&ChrB(c)))
i=i+1
else
stemp=stemp&Chr(c)
End If
Next
subString=stemp
End function
''''''''''''''''''''''''''''''''''''''
''自定义函数toByte，返回一个字符串
''
''
''''''''''''''''''''''''''''''''''''''
Private Function inString(theStart,varStr)
dim i,j,bt,theLen,str
InString=0
Str=toByte(varStr)
theLen=LenB(Str)
for i=theStart to upfile_Stream.Size-theLen
if i>upfile_Stream.size then exit Function
upfile_Stream.Position=i-1
if AscB(upfile_Stream.Read(1))=AscB(midB(Str,1)) then
InString=i
for j=2 to theLen
if upfile_Stream.EOS then
inString=0
Exit for
end if
if AscB(upfile_Stream.Read(1))<>AscB(MidB(Str,j,1)) then
InString=0
Exit For
end if
next
if InString<>0 then Exit Function
end if
next
End Function

Private Sub Class_Terminate
form.RemoveAll
file.RemoveAll
set form=nothing
set file=nothing
upfile_Stream.close
set upfile_Stream=nothing
End Sub

Private function GetFilePath(FullPath)
If FullPath <> "" Then
GetFilePath = left(FullPath,InStrRev(FullPath, "\"))
Else
GetFilePath = ""
End If
End function

Private function GetFileName(FullPath)
If FullPath <> "" Then
GetFileName = mid(FullPath,InStrRev(FullPath, "\")+1)
Else
GetFileName = ""
End If
End function
''''''''''''''''''''''''''''''''''''''
''Hex 返回表示十六进制数字值的字符串
''
''
''''''''''''''''''''''''''''''''''''''
Private function toByte(Str)
dim i,iCode,c,iLow,iHigh
toByte=""
For i=1 To Len(Str)
c=mid(Str,i,1)
iCode =Asc(c)
If iCode<0 Then iCode = iCode + 65535
If iCode>255 Then
iLow = Left(Hex(Asc(c)),2)
iHigh =Right(Hex(Asc(c)),2)
toByte = toByte & chrB("&H"&iLow) & chrB("&H"&iHigh)
Else
toByte = toByte & chrB(AscB(c))
End If
Next
End function
End Class

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''定义FileInfo类
''
''
''
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Class FileInfo
dim FormName,FileName,FilePath,FileSize,FileStart
Private Sub Class_Initialize
FileName = ""
FilePath = ""
FileSize = 0
FileStart= 0
FormName = ""
End Sub

''''''''''''''''''''''''''''''''''''''
''存放文件
''
''
''''''''''''''''''''''''''''''''''''''
Public function SaveAs(FullPath)
dim dr,ErrorChar,i
SaveAs=1
if trim(fullpath)="" or FileSize=0 or FileStart=0 or FileName="" then exit function
if FileStart=0 or right(fullpath,1)="/" then exit function
set dr=CreateObject("Adodb.Stream")
dr.Mode=3
dr.Type=1
dr.Open
upfile_Stream.position=FileStart-1
upfile_Stream.copyto dr,FileSize
dr.SaveToFile FullPath,2
dr.Close
set dr=nothing
SaveAs=0
end function
End Class

下面是调用方法

<%
dim upload,file,formName,iCount
set upload=new upload_wilton ''建立上传对象

''在目录后加(/)
if right(formPath,1)<>"/" then formPath=formPath&"/"

iCount=0

for each formName in upload.file ''列出所有上传了的文件
set file=upload.file(formName) ''生成一个文件对象

file.SaveAs Server.mappath(formPath&file.FileName) ''保存文件

response.write file.FilePath&file.FileName
response.Write("
")
response.write file.FileSize

set file=nothing
next
set upload=nothing ''删除此对象
%>

还有一个setup.asp是设置一些限制文件的参数

<%
dim formPath,uploadsize,FileType,maxpage
uploadsize= "64" ''设置文件大小，单位是 K

maxpage= "10" ''上传文件列表每页显示的个数

formPath= "pic/" ''设置保存目录，以程序所在目录为相对目录，可自己修改或创建。

FileType= ".gif.jpg" ''设置限制上传文件类型，只支持三个字母的扩展名。

文章评论

查看所有0条评论>>